Джереми Блум - Изучаем Arduino - инструметы и методы технического волшебства

- 262 -

Пришло время написать простую программу для проверки работы устройства устранения дребезга и уяснения возможностей аппаратных прерываний Arduino. Наиболее очевидное и полезное применение аппаратных прерываний - опрос внешних входов во время работы программы, в которой присутствуют задержки delay().

Есть много сценариев, в которых это необходимо, мы будем управлять яркостью светодиода, формируя ШИМ-сигнал с помощью функции analogWrite(). Устройство подает на один из трех выводов RGB-светодиода сигнал, варьирующий от 0 до 255 и обратно. Каждый раз при нажатии на кнопку меняется цвет свечения. Это невозможно сделать с помощью опроса состояния вывода в цикле, т. к. момент нажатия кнопки почти наверняка будет пропущен.

Сначала разберемся, что такое переменные volatile. Если переменная будет меняться при выполнении прерывания, ее следует объявить как volatile (нестабильная). Это необходимо для корректной обработки переменной компилятором. Пример объявления переменной как volatile:

volatile int selectedLED = 9;

Для вызова прерывания в Arduino предусмотрена функция attachInterrupt(), находящаяся в setup(). Параметры функции: идентификатор прерывания (или номер контакта для платы Due ), имя функции обработки прерывания и режим запуска прерывания (LOW, CHANGE, RISING или FALLING). В нашей программе объявлено прерывание о (вывод 2 на плате Uno), которое при срабатывании RISING (по фронту) запускает функцию swap()

attachInterrupt(0, swap, RISING);

Осталось написать код функции обработки прерывания swap() и добавить его к основной программе. После подключения прерывания и написания кода функции обработки прерывания вы можете писать остальной текст программы. Каждый раз при вызове прерывания основная программа приостанавливается, выполняется функция обработки прерывания, затем ход основной программы продолжается с того места, где она была прервана. Поскольку прерывание останавливает основную программу, его обработка должна быть очень короткой и не содержать задержки delay(). Теперь все готово для написания программы управления яркостью RGB-светодиода и переключения цвета по нажатию кнопки. Полный текст программы приведен в листинге 12.1.

Листинг 12.1. Аппаратные прерывания, реализующие многозадачность - hw_multitask.ino

// кнопка с аппаратной противодребезговой защитой,

// управляемая прерыванием

// Контакт кнопки

const int BUTTON_INT =0; // Прерывание 0 (вывод 2 для Uno)

const int RED=11;

// Красный вывод RGB-светодиода контакт 11

const int GREEN=10;

// Зеленый вывод RGB-светодиода контакт 10

const int BLUE=9;

// Синий вывод RGB-светодиода контакт 9

- 263 -

// Переменные volatile можно изменять внутри функции обработки прерывания

volatile int selectedLED = RED;

void setup()

{

pinMode (RED, OUTPUT);

pinMode (GREEN, OUTPUT);

pinMode (BLUE, OUTPUT);

// Режим прерывания RISING (переход с LOW на HIGH)

attachInterrupt(BUTTON_INT, swap, RISING);

}

void swap()

{

// Выключить текущий цвет

analogWrite(selectedLED, 0);

// Новое значение для переменной selectedLED

if (selectedLED == GREEN)

selectedLED = RED;

else if (selectedLED == RED)

selectedLED = BLUE;

else if (selectedLED == BLUE)

selectedLED = GREEN;

}

void loop()

{

for (int i = 0; i<256; i++)

{

analogWrite(selectedLED, i);

delay(10);

}

for (int i = 255; i>= 0; i--)

{

analogWrite(selectedLED, i);

delay(10);

}

}

Загрузите программу на плату Arduino, вы увидите изменение яркости одного из цветов (R, G или В) RGB-светодиода от нуля до максимума и обратно. Каждый раз при нажатии на кнопку выбирается следующий цвет с той же яркостью, что и предыдущий.

ПРИМЕЧАНИЕ

Посмотреть видеоурок, демонстрирующий пример аппаратного прерывания Arduino для кнопки без дребезга, можно на странице http://www.exploringarduino.com/content/ch12. Этот видеофайл доступен также на сайте издательства Wiley.

- 264 -

Аппаратные прерывания - не единственный вид прерываний, который возможен для Arduino. Существуют также прерывания по таймеру. В контроллере ATmega328 (установленном на Arduino Uno) есть три аппаратных таймера. На самом деле Arduino по умолчанию использует эти таймеры для функции millis(), работы с delay() и для включения ШИМ при вызове analogWrite(). Хотя в языке программирования Arduino отсутствуют специальные конструкции для работы с таймерами, управляя таймерами вручную, можно генерировать произвольные ШИМ-сигналы на любом контакте и делать многое другое. Далее мы расскажем, как с помощью сторонних библиотек (библиотека TimerOne) управлять 16-разрядным таймером Timer1 в ATmega328. Подобные библиотеки есть и для плат Leonardo, но здесь опишем только работу с Arduino Uno.