Олег Деревенец - Песни о Паскале

{ P_37_1 – вывод множества в файл }

type TSet = set of 1..255; { объявление типа «множество» }

{----- Процедура вывода множества в файл -----}

procedure WriteSet(var aFile: text; const aSet : TSet);

var k : integer;

begin

for k:=1 to 255 do { цикл по всем элементам множества}

if k in aSet { если K входит в множество }

then Write(aFile, k:4); { печатаем в строке }

Writeln(aFile); { по окончании – переход на следующую строку }

end;

{----- Программа для проверки процедуры WriteSet -----}

var S1 : TSet; F: text;

begin

Assign(F, '') ; Rewrite(F); { связываем файл с экраном! }

S1:= [3, 10, 25]; { значение множества }

WriteSet(F, S1); { печатаем }

Readln;

Close(F);

end.

В первой строке объявлен тип данных TSet, он может содержать целые числа от 1 до 255. Процедура распечатки WriteSet принимает по ссылке два параметра: файловую переменную и множество, которое надо распечатать. Внутри процедуры работает цикл FOR, перебирающий все возможные элементы множества. Те из них, что содержатся в нём, печатаются в текущей строке. По завершении цикла оператор Writeln переводит позицию записи на следующую строку файла.

Обратите внимание: множество передано в процедуру по ссылке CONST. Передача в процедуры множеств, строк и других сложных типов данных по ссылкам CONST и VAR — это обычная практика. Так повышается скорость работы программ и уменьшается объём памяти, занимаемый параметрами.

Теперь взгляните на оператор Assign(F,''), который назначает файловой переменной пустое имя файла. Так файловая переменная связывается с экраном дисплея (при выводе данных), либо с клавиатурой (при вводе). А когда вам потребуется вывести результаты в дисковый файл, достаточно будет задать нужное имя файла, не меняя процедуры WriteSet (этот прием – подстановка пустого имени – не работает в Pascal ABCNet).

Примечание. В современные версии Паскаля (Delphi) для обработки множеств введён вариант цикла FOR-IN-DO. С ним распечатка множества станет ещё проще:

for k in aSet do Write(aFile, k:4);

Разобравшись с распечаткой множества, перейдем к вводу его из файла. Есть соображения на этот счет? Здесь пригодится опыт чтения чисел из строки текстового файла, – вспомните обработку классного журнала. Добавить число к множеству мы тоже умеем: для этого надо объединить его с множеством, состоящим из добавляемого числа. На этих идеях построена процедура ввода, показанная ниже вместе с тестирующей её программой.

{ P_37_2 – ввод и вывод числового множества }

type TSet = set of 1..255; { объявление типа «множество» }

{----- Процедура чтения множества из файла -----}

procedure ReadSet(var aFile: text; var aSet : TSet);

var k : integer;

begin

aSet:= [];

While not Eoln(aFile) do begin { пока не конец строки }

Read(aFile, K); { читаем очередное число }

aSet:= aSet+[K]; { и добавляем к множеству }

end;

Readln (aFile); { переход на следующую строку }

end;

{----- Процедура распечатки множества в файл -----}

procedure WriteSet(var aFile: text; const aSet : TSet);

var k : integer;

begin

for k:=1 to 255 do { цикл по всем элементам множества}

if k in aSet { если входит в множество }

then Write(aFile, k:4); { печатаем в строке }

Writeln(aFile); { по окончании переход на следующую строку }

end;

{----- Программа для проверки процедуры ввода -----}

var S1 : TSet; F, D: text;

begin

Assign(F, ''); Rewrite(F); { вывод на экран }

Assign(D, '') ; Reset(D); { ввод с клавиатуры }

S1:= [] ; { перед вводом опустошаем множество }

ReadSet(D, S1); { вводим множество из файла }

WriteSet(F, S1); Readln; { распечатаем для проверки }

Close(F); Close(D);

end.

Полагаю, что комментарии поясняют все. Обязательно проверьте работу этой программы. Учтите, что вводить данные вы будете с клавиатуры: напечатайте в одной строке несколько чисел, разделяя их пробелами, а затем нажмите клавишу Enter.

Освоив ввод и вывод множеств, мы вплотную подошли к полному решению директорской задачи. Напомню, что суть решения заключается всего в одном операторе.

R:= [1..250] – (S1 + S2 + S3);